您最多选择25个主题
主题必须以中文或者字母或数字开头，可以包含连字符 (-)，并且长度不得超过35个字符
60 行
3.2 KiB
60 行
3.2 KiB
// Ref: https://gist.github.com/TheRealMJP/c83b8c0f46b63f3a88a5986f4fa982b1 from MJP
|
|
// Samples a texture with Catmull-Rom filtering, using 9 texture fetches instead of 16.
|
|
// See http://vec3.ca/bicubic-filtering-in-fewer-taps/ for more details
|
|
float4 SampleTextureCatmullRom(in Texture2D<float4> tex, in SamplerState linearSampler, in float2 uv, in float2 texSize)
|
|
{
|
|
// We're going to sample a a 4x4 grid of texels surrounding the target UV coordinate. We'll do this by rounding
|
|
// down the sample location to get the exact center of our "starting" texel. The starting texel will be at
|
|
// location [1, 1] in the grid, where [0, 0] is the top left corner.
|
|
float2 samplePos = uv * texSize;
|
|
float2 texPos1 = floor(samplePos - 0.5f) + 0.5f;
|
|
|
|
// Compute the fractional offset from our starting texel to our original sample location, which we'll
|
|
// feed into the Catmull-Rom spline function to get our filter weights.
|
|
float2 f = samplePos - texPos1;
|
|
float2 f2 = f * f;
|
|
float2 f3 = f2 * f;
|
|
|
|
// Compute the Catmull-Rom weights using the fractional offset that we calculated earlier.
|
|
// These equations are pre-expanded based on our knowledge of where the texels will be located,
|
|
// which lets us avoid having to evaluate a piece-wise function.
|
|
float2 w0 = (1.0f / 6.0f) * (-3.0f * f3 + 6.0f * f2 - 3.0f * f);
|
|
float2 w1 = (1.0f / 6.0f) * (9.0f * f3 - 15.0f * f2 + 6.0f);
|
|
float2 w2 = (1.0f / 6.0f) * (-9.0f * f3 + 12.0f * f2 + 3.0f * f);
|
|
float2 w3 = (1.0f / 6.0f) * (3.0f * f3 - 3.0f * f2);
|
|
|
|
// Otim by Vlad, to test
|
|
// float2 w0 = (1.0 / 2.0) * f * (-1.0 + f * (2.0 - f));
|
|
// float2 w1 = (1.0 / 6.0) * f2 * (-15.0 + 9.0 * f)) + 1.0;
|
|
// float2 w2 = (1.0 / 6.0) * f * (3.0 + f * (12.0 - f * 9.0));
|
|
// float2 w3 = (1.0 / 2.0) * f2 * (f - 1.0);
|
|
|
|
// Work out weighting factors and sampling offsets that will let us use bilinear filtering to
|
|
// simultaneously evaluate the middle 2 samples from the 4x4 grid.
|
|
float2 w12 = w1 + w2;
|
|
float2 offset12 = w2 / (w1 + w2);
|
|
|
|
// Compute the final UV coordinates we'll use for sampling the texture
|
|
float2 texPos0 = texPos1 - 1;
|
|
float2 texPos3 = texPos1 + 2;
|
|
float2 texPos12 = texPos1 + offset12;
|
|
|
|
texPos0 /= texSize;
|
|
texPos3 /= texSize;
|
|
texPos12 /= texSize;
|
|
|
|
float4 result = 0.0f;
|
|
result += tex.SampleLevel(linearSampler, float2(texPos0.x, texPos0.y), 0.0f) * w0.x * w0.y;
|
|
result += tex.SampleLevel(linearSampler, float2(texPos12.x, texPos0.y), 0.0f) * w12.x * w0.y;
|
|
result += tex.SampleLevel(linearSampler, float2(texPos3.x, texPos0.y), 0.0f) * w3.x * w0.y;
|
|
|
|
result += tex.SampleLevel(linearSampler, float2(texPos0.x, texPos12.y), 0.0f) * w0.x * w12.y;
|
|
result += tex.SampleLevel(linearSampler, float2(texPos12.x, texPos12.y), 0.0f) * w12.x * w12.y;
|
|
result += tex.SampleLevel(linearSampler, float2(texPos3.x, texPos12.y), 0.0f) * w3.x * w12.y;
|
|
|
|
result += tex.SampleLevel(linearSampler, float2(texPos0.x, texPos3.y), 0.0f) * w0.x * w3.y;
|
|
result += tex.SampleLevel(linearSampler, float2(texPos12.x, texPos3.y), 0.0f) * w12.x * w3.y;
|
|
result += tex.SampleLevel(linearSampler, float2(texPos3.x, texPos3.y), 0.0f) * w3.x * w3.y;
|
|
|
|
return result;
|
|
}
|